10 A=A+1:IF A=1 THEN LOAD"GDM.OBJ",8,1
15 B=B+1:IF B=1 THEN LOAD"GDM.CODES",8,1
16 REM NEU
20 BM=49664:FORT=0 TO 7:POKE 49438+T,2^T:NEXT:POKE53269,0:POKE53280,0:POKE646,1
25 POKE 53281,0:BUFF=BM+2:POKE53272,23
30 POKE657,128:PRINT"[147][199]EOS [198]ILE [204]INKER  VON [212]HORSTEN [208]ETROWSKI[163][163][163][163][163][163][163][163][163][163][163][163][163][163][163][163]"
35 PRINT " [218]U LINKENDES [198]ILE";:GOSUB 175:FF=0:SF$=IN$
36 CLOSE 15:CLOSE 2:OPEN 15,8,15,"IO":OPEN 2,8,2,"#"
40 IF IN$="$" THEN SF$=CHR$(0)
45 GOSUB 210:IF FF=0  THEN 35
50 PRINT"[198][201][204][197]-[197][201][206][212][210][193][199]:[146]":IF IT<>0 THEN 75
55 IT=1:IS=0
60 PRINT#15,"B-A 0";IT;IS:INPUT#15,REP,DUMMY$,IT,IS
61 IF REP=0 THEN IT=1:IS=0:GOTO 75
62 IF IT=18 THEN IT=19:IS=0:GOTO 60
65 IF REP=65 AND IT=0 THEN PRINT"-[206]ICHTS MEHR FREI !":END
75 POKE RB+21,0:POKE RB+19,IT:POKE RB+20,IS:PRINT"    [199][197][207][211] [198]ILETYP :"
80 PRINT"0  [206]ICHT [199][197][207][211]",,,"1  [194]ASIC",,,,"2  [193]SSEMBLER",,,"4  [211]YSTEM-[196]ATEI",,,
85 PRINT"5  [196]ESK[164][193]CCESSORY",,,"6  [193]PPLIKATION",,,"8  [198]ONT-[198]ILE",,,
90 PRINT"9  [196]RUCKERTREIBER",,,"10 [197]INGABETREIBER"
95 AD=RB+22:PRINT" [201]HRE [215]AHL";:GOSUB 180:GT=VAL(IN$)
100 AD=RB+23:OU$="[211]CHREIBJAHR":GOSUB205:OU$="     -MONAT":GOSUB205
105 OU$="       -TAG":GOSUB205:OU$="    -STUNDE":GOSUB205
110 OU$="    -MINUTE":GOSUB 205
115 PRINT#15,"B-P 2 0":SYS 49193:PRINT#15,"U2:2 0";AT;AS:PRINT"[201]NFOSCHIRM"
120 PRINT#15,"U1:2 0";IT;IS:SYS 49152:POKEBM,0:POKE BM+1,255:POKE BM+2,3
125 POKE BM+3,21:POKE BM+4,191:POKE BM+69,GT:POKE BM+70,0
130 FORT=0 TO 62:POKE 832+T,PEEK(BM+5+T):NEXT:POKE BM+68,129
135 GOSUB 285:PRINT"[147][193]NFANGSADRESSE";:AD=BM+71:GOSUB 185:GOSUB190
140 PRINT"  [197]NDADRESSE";:AD=BM+73:GOSUB 185
145 PRINT"  [211]TARTADRESSE";:AD=BM+75:GOSUB 185
150 PRINT"'[195][204][193][211][211]'";:AD=BM+77:L=20:GOSUB 200
155 PRINT"'[193][213][212][207][210]'";:AD=BM+97:L=19:GOSUB 200
160 PRINT" '[201][206][198][207]'";:AD=BM+160:L=94:GOSUB 200
165 PRINT#15,"B-P 2 0":SYS 49193:PRINT#15,"U2:2 0";IT;IS:PRINT"[198]ERTIG!"
170 CLOSE 2:CLOSE 15:GOTO 445
175 PRINT" :";:OPEN 3,0,0:INPUT#3,IN$:CLOSE 3:PRINT:RETURN
180 GOSUB 175:POKE AD,VAL(IN$):RETURN
185 GOSUB 175:MEM=VAL(IN$)
190 B1=INT(MEM/256):B0=((MEM/256)-INT(MEM/256))*256
195 POKE AD,B0:POKE AD+1,B1:RETURN
200 GOSUB 175:WE$=LEFT$(IN$,L):GOTO 425
205 PRINT OU$;:GOSUB200:POKE AD,VAL(IN$):AD=AD+1:RETURN
210 AT=18:AS=1:PRINT" [196]ISK-[211]EARCH ...":FF=0
215 PRINT#15,"B-P 2 0":PRINT#15,"U1:2 0";AT;AS:SYS 49152:POKE 53280,0:SB=0
220 RB=32*SB+BUFF:INPUT#15,ER,ER$,ET,ES
225 IF ER<>0 THEN PRINT"[196]ISK-[197]RROR ";ER;":";ER$;ET;ES:END
230 SYS 49259,(RB+3),16,NF$:PRINTNF$:LS=LEN(SF$):RI$=RIGHT$(SF$,1)
235 IF RI$<>"*" AND MID$(NF$,LS+1,1)<>"." THEN 265
240 IF RI$="*" AND SF$=LEFT$(NF$,LS-1)+"*"  THEN 250
245 IF SF$<>LEFT$(NF$,LS) THEN 265
250 CN=LEN(NF$)
255 IF MID$(NF$,CN,1)="." AND CN>0 THEN CN=CN-1:GOTO 255
260 SF$=LEFT$(NF$,CN):IT=PEEK(RB+19):IS=PEEK(RB+20):FF=1:RETURN
265 SB=SB+1:IF SB<8 THEN 220
270 AT=PEEK(BUFF-2):AS=PEEK(BUFF-1):IF AT=0 THEN RETURN
275 GOTO 215
280 B1=INT(AD/256):B0=((AD/256)-INT(AD/256))*256:RETURN
285 PRINT"[147] [201]CON [197]DIT[146]":POKE 49425,32:POKE 49430,42
290 SY$="[192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
295 PRINT"  [176]"SY$"[174]"
300 AD=832:FOR Y=0 TO 20
305 PRINT"  [221]";:FORX=0 TO 2:SYS49407,PEEK(AD):AD=AD+1:NEXT X:PRINT"[221]":NEXTY
310 PRINT"  [173]"SY$"[189]"
315 PRINT""TAB(28);"^^^^^"
320 POKE 53269,1:POKE 2040,13:POKE 53248,255:POKE 53249,76:POKE 53288,1
325 POKE 53264,0:X=0:Y=0:OX=2022:OP=0:DD=1107
330 POKE OX,PEEK(OX)AND127:POKE DD,PEEK(DD)OR128
335 GET KEY$:IF KEY$="" THEN 335
340 OX=DD:IF KEY$="" AND X<23  THEN X=X+1
345 IF KEY$="[157]" AND X>0 THEN X=X-1
350 IF KEY$="[145]" AND Y>0 THEN Y=Y-1
355 IF KEY$="" AND Y<20 THEN Y=Y+1
360 IF KEY$<>"Q" THEN 370
365 FORT=0 TO 62:POKE49669+T,PEEK(832+T):NEXT:POKE 53269,0:RETURN
370 IF KEY$<>"R" THEN 390
375 POKE 832,255:POKE 833,255:POKE 834,255:POKE 893,255:POKE 894,255
380 POKE 892,255:FORT=835 TO 889 STEP 3
385 POKE T,PEEK(T)OR128:POKE T+2,PEEK(T+2)OR1:NEXT:GOTO 295
390 IF KEY$="[147]" THEN FORT=832 TO 895:POKE T,0:NEXT:GOTO 295
395 IF KEY$<>" " THEN 415
400 IF (PEEK(BY)AND BI)=BI THEN 410
405 POKE BY,PEEK(BY)OR BI:POKE DD,170:GOTO 415
410 POKE BY,PEEK(BY)AND(255-BI):POKE DD,160
415 DD=1107+Y*40+X:BY=832+(Y*3)+INT(X/8):BI=2^(7-(INT(((X/8)-INT(X/8))*8)))
420 GOTO 330
425 WE$=WE$+CHR$(0):FOR W=1 TO LEN(WE$):WE=ASC(MID$(WE$,W,1))
430 IF WE>64 AND WE<91 THEN WE=WE+32:GOTO 440
435 IF WE>192 AND WE<219 THEN WE=WE-128
440 POKE AD-1+W,WE:NEXT W:RETURN
445 PRINT" ([206])OCHMAL ODER ([197])NDE ?"
450 GET KEY$:IF KEY$="" THEN 450
455 IF KEY$="N" OR KEY$="[206]" THEN RUN20
460 IF KEY$="E" OR KEY$="[197]" THEN END
465 GOTO 450